!-------------------------------------- LICENCE BEGIN ------------------------------------
!Environment Canada - Atmospheric Science and Technology License/Disclaimer,
!                     version 3; Last Modified: May 7, 2008.
!This is free but copyrighted software; you can use/redistribute/modify it under the terms
!of the Environment Canada - Atmospheric Science and Technology License/Disclaimer
!version 3 or (at your option) any later version that should be found at:
!http://collaboration.cmc.ec.gc.ca/science/rpn.comm/license.html
!
!This software is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY;
!without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
!See the above mentioned License/Disclaimer for more details.
!You should have received a copy of the License/Disclaimer along with this software;
!if not, you can write to: EC-RPN COMM Group, 2121 TransCanada, suite 500, Dorval (Quebec),
!CANADA, H9P 1J3; or send e-mail to service.rpn@ec.gc.ca
!-------------------------------------- LICENCE END --------------------------------------
!
!
!  X X X X X X X X X X X X X X X X X X X X X X X X X X X X X X X X X X X
!

      subroutine inmi_pc(pdpsi,pdchi,pdvort,pddiv),10
!
!**s/r inmi_pc  - Controls the computation of initialized (psi,chi) analysis increments.
!                 Ref.: Temperton & Roch (1991).MWR 116, 667-677.
!
!Author  : Luc Fillion - ARMA/EC - 1 May 2007.
!Revision: 
!: Luc Fillion - ARMA/EC - May 2010 - Implemented on v_11_01b of 3dvar.
!
!     -------------------
!
!Arguments
! out
!  pdpsi = del(psi) in gridpoint space
!  pdchi = del(chi) in gridpoint space
! in
!  pdvort = del(vort) in vertical mode space
!  pddiv  = del(div) in vertical mode space
!
      IMPLICIT NONE
!
#include "taglam4d.cdk"
#include "pardim.cdk"
#include "comdim.cdk"
#include "comcst.cdk"
#include "comlun.cdk"
#include "comode.cdk"
!
      real*8 pdpsi(ni,nflev,nj)
      real*8 pdchi(ni,nflev,nj)
      real*8 pdvort(ni,nflev,nj)
      real*8 pddiv(ni,nflev,nj)
!
      character*3 clvar
      character*8 clletiket
      logical llwrite
      integer ji,jj,jk,jmode
      real*8 zf0,zf02,zcon,zicon
      real*8 zvert1(nflev),zvert2(nflev)
      real*8 zw2d1(ni,nj)
      real*8 zw2d2(ni,nj)
      real*8 zwh(ni,nj)
      real*8 zwh2(ni,nj)
!
!!
      call zero(ni*nj*nflev,pdpsi)
      call zero(ni*nj*nflev,pdchi)
!
      zf0=2.*romega
      zf02=zf0**2
      llwrite = .false.
!
!*1.  Loop on vertical normal modes
!     -----------------------------
!
      do jmode=1,nvmod
        do ji=1,ni
          do jj=1,nj
            zwh(ji,jj)=pdvort(ji,jmode,jj)
          enddo
        enddo
        call invlap(zwh2,zwh,'P')
        do ji=1,ni
          do jj=1,nj
            pdpsi(ji,jmode,jj)=zwh2(ji,jj)
          enddo
        enddo
!
        do ji=1,ni
          do jj=1,nj
            zwh(ji,jj)=pddiv(ji,jmode,jj)
          enddo
        enddo
        call invlap(zwh2,zwh,'S')
        do ji=1,ni
          do jj=1,nj
            pdchi(ji,jmode,jj)=zwh2(ji,jj)
          enddo
        enddo
      enddo
!
!*2.  Transform to gridpoint space
!
! Psi
      do jj=1,nj
        do ji=1,ni
          call zero(nflev,zvert1)
          do jk=1,nflev
            zvert1(jk)=pdpsi(ji,jk,jj)
          enddo
          call mxv(zvert2,vmat,zvert1,nflev,nflev)
          do jk=1,nflev
            pdpsi(ji,jk,jj) = zvert2(jk)
          enddo
        enddo
      enddo
!
! Chi
      do jj=1,nj
        do ji=1,ni
          call zero(nflev,zvert1)
          do jk=1,nflev
            zvert1(jk)=pdchi(ji,jk,jj)
          enddo
          call mxv(zvert2,vmat,zvert1,nflev,nflev)
          do jk=1,nflev
            pdchi(ji,jk,jj) = zvert2(jk)
          enddo
        enddo
      enddo
!
!*3.  Output on file if desired
!
      if(llwrite) then
        clletiket='INMIPPCC'
        clvar = 'PP '
        call write_fld(pdpsi,clvar,clletiket,nflev)
        clvar = 'CC '
        call write_fld(pdchi,clvar,clletiket,nflev)
      endif
!
      return
      end