!-------------------------------------- LICENCE BEGIN ------------------------------------
!Environment Canada - Atmospheric Science and Technology License/Disclaimer,
!                     version 3; Last Modified: May 7, 2008.
!This is free but copyrighted software; you can use/redistribute/modify it under the terms
!of the Environment Canada - Atmospheric Science and Technology License/Disclaimer
!version 3 or (at your option) any later version that should be found at:
!http://collaboration.cmc.ec.gc.ca/science/rpn.comm/license.html
!
!This software is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY;
!without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
!See the above mentioned License/Disclaimer for more details.
!You should have received a copy of the License/Disclaimer along with this software;
!if not, you can write to: EC-RPN COMM Group, 2121 TransCanada, suite 500, Dorval (Quebec),
!CANADA, H9P 1J3; or send e-mail to service.rpn@ec.gc.ca
!-------------------------------------- LICENCE END --------------------------------------
!

      subroutine rft8( r, a, inc, jump, lot, isign, n ) 2

C
      implicit none
#include "taglam4d.cdk"
C
      integer inc, jump, lot, isign, n
      real*8  r(*), a(*)
C
      integer i, j, k, kk, k1
C
      real*8 zero, half, one, two
      parameter( zero = 0.0 )
      parameter( half = 0.5 )
      parameter( one  = 1.0 )
      parameter( two  = 2.0 )

      real*8 oneon, del, angle, cc, ss, faz
      integer ij
      ij(i,j) = 1 + ( j - 1 ) * jump + i * inc

      oneon = one/n
      del   = acos( - one ) * two/n
C
C     The transform  is along the i-th direction
C     and the indexing is 1+(j-1)*jump+i*inc (i=0,2*[n/2]+1,j=1,lot)
C     in the input & output fields
C
      if ( isign .eq. -1 ) then
C
C     transform from gridpoint to fourier
C
      do k=0,2*(n/2)+1
         do j=1,lot
            r( ij(k,j) ) = zero
         enddo
      enddo

      do k=0,n/2

         kk = 2 * k
         k1 = kk + 1

         do i=0,n-1

            angle = k * i * del
            cc =   oneon * cos( angle )
            ss = - oneon * sin( angle )

            do j=1,lot
               r( ij(kk,j) ) = r( ij(kk,j) ) + cc * a( ij(i,j) )
               r( ij(k1,j) ) = r( ij(k1,j) ) + ss * a( ij(i,j) )
            enddo

         enddo

      enddo

      elseif ( isign .eq. +1 ) then
C
C    transform from fourier to gridpoint
C
      faz = - one * mod( n + 1, 2 )
      do i=0,n-1

         faz = - faz
         do j=1,lot
            r( ij(i,j) ) = a( ij(0,j) ) + faz * a( ij(2*(n/2),j) )
         enddo

         do k=1,(n-1)/2

            kk = 2 * k
            k1 = kk + 1
            angle = k * i * del
            cc = two * cos( angle )
            ss = two * sin( angle )

            do j=1,lot
               r( ij(i,j) ) = r( ij(i,j) ) + cc * a( ij(kk,j) )
     %                                     - ss * a( ij(k1,j) )
            enddo

         enddo

      enddo

      endif
         
      return
      end